TIMING: Verifying your E-Prime Go Timing [35028]

This article applies to:

E-Prime Go 1.0

Detail

To verify timing of the participant's machine, please insert an InLine Object at the beginning of SessionProc with the following script.

Sleep 50

　

'nTestDuration controls how long to run the test

Const nTestDuration As Long = 2000

Const cMAXBINS As Long = 100

　

Dim StartTime As Long

　

'log the current time

StartTime = Clock.Read

　

' Declare and initialize counter array

Dim i As Long

Dim nBinCnt(cMAXBINS) As Long

For i = 0 To cMAXBINS

nBinCnt(i) = 0

Next i

　

Dim nThisTime As Long

Dim nLastTime As Long

Dim nEndTime As Long

Dim nDiff As Long

Dim nStartMicro As Long

Dim nStopMicro As Long

　

Dim nAnalysisStartTime As Long

Dim nAnalysisStopTime As Long

　

Dim nTotalSamples As Long

Dim nBinSumError As Long

Dim nBinSumErrorLarge As Long

Dim nMaxBin As Long

Dim nErrorSamples As Long

　

' Error Handler

On Error GoTo BinError

　

' Loop until we get a transition

' to allow us to start the test

' as close to transition as possible

nThisTime = Clock.Read

Do While nThisTime = Clock.Read

' DO NOTHING

Loop

nLastTime = nThisTime + 1

nEndTime = nLastTime + nTestDuration

　

nStartMicro = Clock.ReadMicrosec

　

Do

' Read the clock

nThisTime = Clock.Read

' Determine the timing error on this read (if any).

nDiff = nThisTime - nLastTime

' Update the count for this bin

' NOTE: If the diff is < 0 or > cMAXBINS then

' a runtime error will occur and will be trapped below

nBinCnt(nDiff) = nBinCnt(nDiff) + 1

' Update for next iteration

nLastTime = nThisTime

Loop While nThisTime < nEndTime

　

nStopMicro = Clock.ReadMicrosec

nAnalysisStartTime = Clock.Read

　

' Log results

For i = 0 To cMAXBINS

nTotalSamples = nTotalSamples + nBinCnt(i)

If i > 1 Then

nErrorSamples = nErrorSamples + nBinCnt(i)

nBinSumError = nBinSumError + (nBinCnt(i) * (i - 1))

If nBinCnt(i) > 0 Then nMaxBin = i

If i > 11 Then nBinSumErrorLarge = nBinSumErrorLarge + (nBinCnt(i) * (i - 1))

End If

Next i

　

c.SetAttrib "StartMicro", nStartMicro

c.SetAttrib "StopMicro", nStopMicro

c.SetAttrib "TotalSamples", nTotalSamples

c.SetAttrib "ValidClock", nBinCnt(1)

c.SetAttrib "ValidClockPercent", Format(CDbl(nBinCnt(1)) / CDbl(nTestDuration), "0.0000%")

c.SetAttrib "ValidSamples", nBinCnt(0) + nBinCnt(1)

c.SetAttrib "ValidSamplesPercent", Format(CDbl(nBinCnt(0) + nBinCnt(1)) / CDbl(nTotalSamples), "0.0000%")

c.SetAttrib "ErrorSamples", nErrorSamples

c.SetAttrib "ErrorSamplesPercent", Format(CDbl(nErrorSamples) / CDbl(nTotalSamples), "0.0000%")

c.SetAttrib "SampleRate", Format(CDbl(nTotalSamples) / CDbl(nTestDuration), "0.0000")

c.SetAttrib "BinNSumError", nBinSumError

c.SetAttrib "BinNSumErrorPercent", Format(CDbl(nBinSumError) / CDbl(nTestDuration), "0.0000%")

c.SetAttrib "BinNSumErrorLarge", nBinSumErrorLarge

c.SetAttrib "BinNSumErrorLargePercent", Format(CDbl(nBinSumErrorLarge) / CDbl(nTestDuration), "0.0000%")

c.SetAttrib "MaxBin", nMaxBin

nAnalysisStopTime = Clock.Read

　

'Flag if data needs reviewed

Dim bNeedReview As Boolean

bNeedReview = False

If nMaxBin > 10 Then bNeedReview = True

If (CDbl(nBinCnt(1)) / CDbl(nTestDuration)) < 0.99 Then

bNeedReview = True

End If

If (CDbl(nBinSumErrorLarge) / CDbl(nTestDuration)) > 0.01 Then

bNeedReview = True

End If

If (CDbl(nBinSumError) / CDbl(nTestDuration)) > 0.01 Then

bNeedReview = True

End If

If (CDbl(nTotalSamples) / CDbl(nTestDuration)) < 4 Then

bNeedReview = True

End If

c.SetAttrib "ReviewStatus", IIf(bNeedReview, "Needs Review", "OK")

　

GoTo BinTestComplete

　

BinError:

　

c.SetAttrib "ERROR", "Error happened in bin test and the diff was " & nDiff

c.SetAttrib "ReviewStatus", "FAIL"

　

Resume BinTestComplete

　

BinTestComplete:

The script runs a test for 2 seconds to see if a machine meets our requirements. A quick way to verify if the data is good is to review the ReviewStatus column in the resulting .edat3 file. If the column states "OK", the machine meets our requirements. If it states "Needs Review", you need to examine the data more in depth to see if the data can be used. Review the following if Needs Review is found:

1. SampleRate - If it is less than 4, the machine fails and the data should not be used. If greater than 4, continue to the next step.
2. BinNSumErrorLargePercent - Note the percentage value in the data file. This is the percentage of error above 11ms. If this is above 0.01%, we do not recommend using the data.

NOTE: It is up to the researcher to determine how much error is inconsequential.

If the ReviewStatus column states "FAIL", a bin error greater than 100ms occurred. The amount of error for the failed bin can be found under the ERROR column. We do not recommend using the data.

See Also:

TIMING: E-Prime Go Timing Data [35163]

TIMING: Verifying your Clock and Timing in E-Prime [34371]